Metin İçeren Alanları Toplama

Selamlar,
C131 hücresindeki formülünüz
=TOPLA.ÇARPIM((A1:A129=A131)*(C1:C129=B131);(C1:C129))
ve
C132 hücresindeki formülünüz
=TOPLA.ÇARPIM((A1:A129=A131)*(C1:C129=B132);(C1:C129))
şeklinde...

** formülde ;(C1:C129) şeklinde kullanmak, hücrelerde BOŞ("") değerleri formüllerle gelip, hücrelerde METİN bulunması durumunda TOPLAMA işlemi için kullanılır. METİN olması durumunda Noktalı virgül yerine *(Çarpım) işlemi yaparsanız HATA verecektir.
** Oysa ki, siz SAYMA işlemi yapmak istiyorsunuz.. O nedenle ;(C1:C129) ibaresine hiç gerek yok...

** Diğer bir olayınız ise,
5/A gibi sınıflar A1:A129 değil, B1:B129 aralığında

Yani formülleriniz.
=TOPLA.ÇARPIM((B1:B129=A131)*(C1:C129=B131))
ve
=TOPLA.ÇARPIM((B1:B129=A131)*(C1:C129=B132))
şeklinde olmalı...
Ancak, bu formüller kopyalanarak çoğaltılmaya uygun değiller...
(C131 ve C132 için yazılan formülleri göreceli ve sabit referans şeklinde yapıp ,ikişerli olarak kopyalayabilirsiniz tabi ki...)
Şimdi
A131:A142 aralığında Birleştirilmiş hücreler bulunduğundan
ve de TEK formül yazıp, hem sağa ve hem de aşağıya kopyalamak istediğinizde
C131 hücresine

=TOPLA.ÇARPIM(($B$1:$B$129=ARA(2;1/($A$131:$A131<>"");$A$131:$A131))*($C$1:$C$129=$B131))

formülünü yazıp sağa ve aşağıya doğru kopyalayabilirsiniz...

Burada,
ARA(2;1/($A$131:$A131<>"");$A$131:$A131)
ile
formülün bulunduğu satıra göre A kolonundaki en son dolu hücre değerini verecektir.
Örneğin formülümüz
C138 de ise
ARA(2;1/($A$131:$A138<>"");$A$131:$A138)
olacak ve A137 de değer olup, A138 BOŞ olduğundan A137 deki değer olan 5/D yi verecektir.

Formülde
=TOPLA.ÇARPIM(($B$1:$B$129=ARA(2;1/($A$131:$A131<>"");$A$131:$A131))*(C$1:C$129=$B131))

C kolonundaki sabitlemeler göreceli olacak... Hatalı yazmışım...

Bu arada,
ARA(2;1/($A$131:$A131<>"");$A$131:$A131) yerine
Evet ve Hayırdan oluşan ikili hücreler olduğundan
EĞER($A131="";$A130;$A131)
şeklinde de yazılabilir.
Yani formül şöyle de olabilir...
=TOPLA.ÇARPIM(($B$1:$B$129=EĞER($A131="";$A130;$A131))*(C$1:C$129=$B131))

Teşekkürler @52779
İnceliyorum formüllerinizi
Örnek dosyada A:A sütununda sınıf ve şubeler vardı son anda sıra numarası eklediğim için benim formül farklı olmuş anlatımda tabiki o şekilde kalmış.

Teşekkürler 52779

Aşağıdaki şekilde formüller ihtiyacımı karşılıyor

Benim asıl hatam şuymuş

C131 hücresine =TOPLA.ÇARPIM(($B$1:$B$129="5/A")*(C$1:C$129="Evet")) şeklinde defalarca yazdım hep 0 değeri verdiği için çalışmıyor gibi düşünerek alternatif formüller yazdım ama hep sıfır gösteriyordu

şimdi baktığımda zaten 5/A sınıfında Evet tercihi hiç yokmuş C sütunu için.... Elbette Evet seçeneği var ama diğer şubeler içinmiş o an bunu farkedemedim şuan farkediyorum

Evet İçin

Hayır İçin

Teşekkür ediyorum...
Belki de,
C143 hücresindeki Toplam için alternatif olarak
=ETOPLA($B$131:$B$142;$B131;C$131:C$142)
yazıp, sağa ve aşağıya kopyalanabilir...

C131 hücresine =TOPLA.ÇARPIM(($B$1:$B$129="5/A")*(C$1:C$129="Evet")) şeklinde defalarca yazdım hep 0 değeri verdiği için çalışmıyor gibi düşünerek alternatif formüller yazdım ama hep sıfır gösteriyordu

Bu olay bende de çok oluyor...

Şu sayısı nasıl bulabilirim?

$B$1:$B$129="5/A"
C$1:C$129="Evet" veya "Hayır" ikisinden birinin kullananların toplamı

=TOPLA.ÇARPIM(($B$1:$B$129="5/A")*((C$1:C$129="Evet")+(C$1:C$129="Hayır")))

Formüllerde, çarpımlar VE, Toplamlar YADA karşılığındadır.

DİZİ şeklinde yazacağım derseniz

=TOPLA.ÇARPIM(($B$1:$B$129="5/A")*(C$1:C$129={"Evet";"Hayır"}))

şeklinde de yazabilirsiniz...