Sıfırdan Farklı Değerleri Olanları Alfabetik Listeleme

[kmlzdmr]

Excel Versiyonu

Excel 2016

Excel Sürümü

64 Bit

Excel Dili

Türkçe

Merhaba,
Forumda #Epak ambalaj tarafından açılmış konu için farklı formül geliştirmeye çalıştım ama çözemedim.
URL adresi: .....------https://www.exceldestek.com/konu/dizi-formul-uygulama-yardimi-alabilir-miyiz.5442/-------
'Çözüldü - Dizi formül uygulama yardımı alabilir miyiz
Bu nedenle ve excel destek forum kurallarına uygun olacağını düşündüğümden yeni konu oluşturmak istedim.

soru 1 -
W3 hücresinde =EĞER(P3<>0;MAK($W$2:W2)+1;"") yardımcı sütun formülü varken X3 hücresindeki formül ile P sütunundaki sıfır değerler haricindeki firma unvanlarını
listelemek istedim ama =EĞER(SATIR()-2>MAK($W$3:$W$121);"";İNDİS($O$3:$W$121;KAÇINCI(SATIR()-2;$W$3:$W$121;0);SÜTUN()-15)) bu formülde
W sütunundaki tespit rakamlarını sıralayabildim. Firma isimleri sıralamak için bu formül nasıl düzeltilebilir.

Soru 2- Soru 1 deki durumun alternatif çözümü olarak firma isimlerinin sıralamasını alfabetik olarak yapacak formül geliştirilecek.

Soru 3 - Z sütununda =EĞER(SATIR()-2>MAK($W$3:$W$121);"";İNDİS($O$3:$W$121;KAÇINCI(SATIR()-2;$W$3:$W$121;0);SÜTUN()-17))
formül yazılı iken AA sütununa =EĞERHATA(İNDİS($O$3:$W$120;KAÇINCI(Z3;$W$3:$W$120;0);1);"") formül uygulayarak alternatif oluşturmaya çalıştığımda
56. sıralamadan sonra ( satır 59 ve aşağısında ) "Zeytinli" ismini devamlı getirmesi nedendir. Bu formül Nasıl düzeltilir. "Zeytinli" ismi O3 hücresinde olup O sütununun ilk sıfır değeri olan firma ismi olduğunu gözlemledim.

konu için yardımcı olabilir misiniz?

 

Dizi formül uygulama yardımı alabilir miyiz

Hücre İçerisindeki Son Parçaları Silme

[Ömer BARAN]

Merhaba @kmlzdmr

Normal ve alfabetik listeleme için TEK YARDIMCI SÜTUN kullanmanın yeterli olacağını düşünerek kendi çözüm önerimi vereyim.

Aşağıdaki;
-- W sütununda (yardımcı sütun) birinci formül,
-- normal listeleme için ikinci formül (CTRL+SHIFT+ENTER ile dizi formülü uygulaması),
-- alfabetik sıralama için üçüncü formül
kullanılabilir.

=($P3<>0)*(EĞERSAY($O$3:$O$120;"<="&$O3)+SATIR()/1000)

=EĞER(SATIR($A1)>EĞERSAY($W$3:$W$120;">0");"";İNDİS($O$3:$O$120;KÜÇÜK(EĞER($W$3:$W$120>0;SATIR($W$3:$W$120));SATIR($A1))-2))

=EĞER(SATIR(A1)>EĞERSAY($W$3:$W$120;">0");"";İNDİS($O$3:$O$120;KAÇINCI(KÜÇÜK($W$3:$W$120;EĞERSAY($W$3:$W$120;0)+SATIR($A1));$W$3:$W$120;0)))

 

[kmlzdmr]

Ömer Baran üstadım çok teşekkür ederim. şimdi bakıyorum.

 

[kmlzdmr]

Üstadım Harika bir işlem...

 

[Ali Kırksekiz]

Tek formülle birşeyler yaptım kontrol edersiniz.

=EĞER(SATIRSAY(A$1:A1)>EĞERSAY(P$3:P$1200;"<>0");"";İNDİS(O$3:O$1200;KÜÇÜK(EĞER(P$3:P$1200<>0;SATIR(P$3:P$1200)-SATIR(P$3)+1);SATIRSAY(A$1:A1))))

CTRL+SHIFT+ENTER ile giriniz . Dizi formülüdür.

 

[Ali Kırksekiz]

Alfabetik sıralayacak iseniz , aralığınıza dinamik liste oluşturun.

Örneğin listeniz AB3:AB8 aralığında olsun.

Küçükten büyüğe sıralayacaksanız AC1'e <" işareti koyun. Büyükten küçüğe sıralayacaksanız AC1'e > işaretini koyun

AC3 hücresine de

=İNDİS($AB$3:$AB$58; KAÇINCI(0;EĞERSAY($AB$3:$AB$58;$AC$1&$AB$3:$AB$58)- TOPLA(EĞERSAY($AB$3:$AB$58;"="&AB$2:AB2));0))

yazıp CTRL+SHIFT+ENTER ile formülü girip aşağı doğru çekiniz.

 

[kmlzdmr]

Sayın Ali Kırksekiz çok teşekkür ederim.

 

[ahmetkaraaslan]

@kmlzdmr
365 Versiyonlara göre =FİLTRE(O3:O120;P3:P120;">0")