Her Bir Sayı için Sıralı Sayı Dizisi oluşturma

  • Konuyu başlatan Konuyu başlatan 52779
  • Başlangıç tarihi Başlangıç tarihi
52779

Kısa Açıklama

Her Bir Sayı için Sıralı Sayı Dizisi oluşturma isimli başlıkta, ilgili işlemlere dair detaylar yer almaktadır.
Ekli dosyalar
Tarihe göre sırala Oylamaya göre sırala
Merhabalar Alternatif olsun.

[REPLY]=LET(c;MUTLAK(FİLTRE(B2:B7;ESAYIYSA(B2:B7)));m;MAK(c);MOD(KÜÇÜK(EĞER(SIRALI(;m)<=c;SIRALI(SATIRSAY(c);m;0));SIRALI(TOPLA(c)));m)+1)[/REPLY]
 
Oyla 0 Olumsuz oyla
1660269274029.webp

Önerilen çözümlerin formüllerini bir sayfada toparlamaya çalışıyorum.

Klasik yöntemle çözüm önerilerimi yazacak olursam
Formüller DİZİ Formüldür.
Formüller F2 hücresine yazılır. Girişler CTRL + SHIFT + ENTER ile yapılır. Formüller aşağıya doğru kopyalanır.

Not : Her ne kadar, soruda, verilen Sayı değerleri, TAMSAYI ve SAYI olsa da, cevaplarda, Ondalıklı sayı yazılırsa Tamsayı olarak değerlendirilmesi ve de Sayı biçiminin Sayı görünümlü METİN olması durumları da değerlendirilmeye alındı.


EĞER / SATIRSAY / TOPLA / ESAYIYSA / MUTLAK / TAMSAYI / EĞERHATA / TOPLAMA / SATIR / EĞERSAY / TOPLA

[REPLY]=EĞER(SATIRSAY(F$1:F1)<=TOPLA(EĞER(ESAYIYSA(--$B$2:$B$7);TAMSAYI(MUTLAK(--$B$2:$B$7));0));EĞER(EĞERHATA(--F1;0)=EĞERHATA(TAMSAYI(MUTLAK(İNDİS($B$2:$B$7;TOPLAMA(15;6;(SATIR($B$2:$B$7)-SATIR($B$2)+1)/(ESAYIYSA(--$B$2:$B$7));EĞERSAY(F$1:F1;1)))));0);1;TOPLA(F1;1));"")[/REPLY]

TOPLA / SATIRSAY / İNDİS / DÇARP / SATIR / DEVRİK_DÖNÜŞÜM / EĞER / ESAYIYSA / MUTLAK / TAMSAYI / KAÇINCI

[REPLY]=EĞER(SATIRSAY($1:1)<=TOPLA(EĞER(ESAYIYSA(--$B$2:$B$7);TAMSAYI(MUTLAK(--$B$2:$B$7));0));SATIRSAY($1:1)-İNDİS(DÇARP(--(SATIR($B$2:$B$7)>DEVRİK_DÖNÜŞÜM(SATIR($B$2:$B$7)));EĞER(ESAYIYSA(--$B$2:$B$7);TAMSAYI(MUTLAK(--$B$2:$B$7));0));KAÇINCI(SATIRSAY($1:1);1+DÇARP(--(SATIR($B$2:$B$7)>DEVRİK_DÖNÜŞÜM(SATIR($B$2:$B$7)));EĞER(ESAYIYSA(--$B$2:$B$7);TAMSAYI(MUTLAK(--$B$2:$B$7));0))));"")[/REPLY]
 
Son düzenleme:
Oyla 0 Olumsuz oyla
Soru olarak verilen listede
** Ondalıklı SAYI yazılması
** Sayı Biçiminin METİN olması yani, Sayı görünümlü METİN olması
durumları da dikkate alınarak

Excel365 Tek Formül - Dökülmeli olarak çözüm önerilerim
(Formül sadece F2 hücresine yazılacak... Sonuçlar liste olarak dökülecek)

METİNBÖL (Insider Beta Kanalı) - BYROW - LAMBDA - METİNBİRLEŞTİR
[REPLY]=--METİNBÖL(METİNBİRLEŞTİR("|";;BYROW(B2:B7;LAMBDA(s;EĞERHATA(METİNBİRLEŞTİR("|";;SIRALI(TAMSAYI(MUTLAK(--s))));""))));;"|")[/REPLY]

XMLFİLTRELE - BYROW - LAMBDA - METİNBİRLEŞTİR
[REPLY]=XMLFİLTRELE("<x><y>"&YERİNEKOY(METİNBİRLEŞTİR("|";;BYROW(B2:B7;LAMBDA(s;EĞERHATA(METİNBİRLEŞTİR("|";;SIRALI(TAMSAYI(MUTLAK(--s))));""))));"|";"</y><y>")&"</y></x>";"//y")[/REPLY]

SCAN - LAMBDA - İNDİS - KAÇINCI
[REPLY]=LET(alan;EĞER(ESAYIYSA(--B2:B7);TAMSAYI(MUTLAK(--B2:B7));0);a;SIRALI(TOPLA(alan));b;SCAN(0;alan;LAMBDA(x;y;TOPLA(x;y)));EĞERHATA(a-İNDİS(b;KAÇINCI(a;1+b));a))[/REPLY]

DÇARP - İNDİS - KAÇINCI
[REPLY]=LET(alan;B2:B7;x;EĞER(ESAYIYSA(--alan);TAMSAYI(MUTLAK(--alan));0);a;SIRALI(TOPLA(x));b;DÇARP(--(SATIR(alan)>DEVRİK_DÖNÜŞÜM(SATIR(alan)));x);EĞERHATA(a-İNDİS(b;KAÇINCI(a;1+b));a))[/REPLY]

DÇARP - KAÇINCI - DİZİOLUŞTUR - LAMBDA - İNDİS
[REPLY]=LET(a;B2:B7;b;EĞER(ESAYIYSA(--a);TAMSAYI(MUTLAK(--a));0);x;SIRALI(TOPLA(b));y;DÇARP(--(SATIR(a)>DEVRİK_DÖNÜŞÜM(SATIR(a)));b);w;KAÇINCI(x;y+1);DİZİOLUŞTUR(SATIRSAY(w);;LAMBDA(r;c;TOPLA(--(İNDİS(w;SIRALI(r))=İNDİS(w;r))))))[/REPLY]

SCAN - LAMBDA - KAÇINCI - DÇARP
[REPLY]=LET(a;B2:B7;b;EĞER(ESAYIYSA(--a);TAMSAYI(MUTLAK(--a));0);f;FİLTRE(b;b<>0);s;SIRALI(TOPLA(f));sc;SCAN(0;f;LAMBDA(x;y;TOPLA(x;y)));w;EĞERHATA(KAÇINCI(s;sc+1);0)+1;DÇARP((SIRALI(SATIRSAY(w))>=SIRALI(;SATIRSAY(w)))*(w=DEVRİK_DÖNÜŞÜM(w));--(w<>"")))[/REPLY]
 
Oyla 0 Olumsuz oyla
Yanıt için giriş yapmanız veya üye olmanız gerekir.
Benzer Konular Popüler İçerikler Daha Fazlası
Geri
Üst