Çoklu Koşul ile Eşitleme Yapma

[teyadih]

Excel Versiyonu

Excel 2016

Excel Sürümü

32 Bit

Excel Dili

Türkçe

Merhaba arkadaşlar ekli dosyada da açıkladığım üzere mantıksal sınama alanı tek, karşılaştıracağı detay ise birden fazla olacak şekilde doğrulama formülü yazılabilir mi?

 

Tüm Sayfaları Kapsayacak Excel Formülü Yazma

Belirli Kurala Göre Veri Çekip Toplama

[52779]

Selamlar,
Yanlış yorumlamıyor isem,
I5 hücresinde yazılmaya çalışılan formül için

=ESAYIYSA(KAÇINCI(AY(F35)-1;{1;3;5;7;8;10;12};0))

ya da

=YADA(AY(F35)-1={1;3;5;7;8;10;12})

formülünü kullanabilirsiniz.

Not : Belirtmeliyim ki, AY(F35)-1 dediğinizde sonuç 12 olamaz. En büyük değer 12 - 1 = 11 olacaktır. Ancak, sarı zeminli alanda (aynı zamanda yazmaya çalıştığınız formülde de var ve o nedenle ben değişiklik yapmadım) 12 sayısı da mevcut. Ben değişiklik yapmadan direkt olarak kullandım.

 

[teyadih]

Teşekkür ederim 52779 uygulayıp dönüş yapacağım. 12.ay ile ilgili sıkıntı çıkacaktır dediğiniz gibi o kısma başka bir çözüm bulmalıyım

 

[teyadih]

Merhaba 52779 formül tamam. Ancak formülün içine DOĞRU";"YANLIŞ") yazmadan da sonuç alınacağı aklıma gelmediği için bu şekilde örnek vermiştim. Size zahmet formülü formülün içinde DOĞRU";"YANLIŞ") yazacak şekilde düzenleyebilir misiniz?
Bana lazım olanı 1;3;5;7;8;10;12 ye eşitse 1 yazsın değilse boş bıraksın

 

[52779]

Selamlar,

Formüller direkt olarak DOĞRU ya da YANLIŞ değerlerini üretirler
Eğer sonuçlar 1 ya da 0 üretsin derseniz, Formüllere, sayıya çevir işlemi uygulamak yeterli olacaktır.
Bu durumda, formüllerin başına 1* yazarsanız iş görecektir. (1* yerine, 0+ ya da -- (iki tire işareti) de yazılabilir.)
Yani, =1*YADA(AY(F35)-1={1;3;5;7;8;10;12}) gibi...

Formüllerin sonuçları 1 ya da "" (Boş) olacaksa,
=EĞERHATA(1/(1/ESAYIYSA(KAÇINCI(AY(F35)-1;{1;3;5;7;8;10;12};0)));"")
ya da diğer formül için
=EĞERHATA(1/(1/YADA(AY(F35)-1={1;3;5;7;8;10;12}));"")
şeklinde EĞERHATA işlevine sarılabilir.

Ya da direkt EĞER işleviyle yapılabilir.
=EĞER(ESAYIYSA(KAÇINCI(AY(F35)-1;{1;3;5;7;8;10;12};0));1;"")
ya da diğer formül için
=EĞER(YADA(AY(F35)-1={1;3;5;7;8;10;12});1;"")


Not :

Teşekkür ederim 52779 uygulayıp dönüş yapacağım. 12.ay ile ilgili sıkıntı çıkacaktır dediğiniz gibi o kısma başka bir çözüm bulmalıyım

Bir tahmin :
F35 hücresinde yazılan tarihin 1 ay öncesinin SON gününü (ya da AYNI gününü) arıyor olabilirsiniz. Bu durumda 1. ay (Ocak) için 1 önceki Ay Aralık (12.ay) olacaktır. Sizde de, 12. ay aramalarında problem olmadan bulunabilecektir.
Bunun için AY(F35)-1 yerine
1 önceki Ayın SON günü için : AY(SERİAY(F35);-1))
1 önceki Ayın AYNI günü için : AY(SERİTARİH(F35);-1))
şeklinde yazılabilir.

 

[teyadih]

Teşekkür ederim 52779 elinize sağlık. Uygulayıp dönüş yapacağım