Brütten Nete 2025

Brütten Nete 2025

İndir
Genel Bakış İncelemeler (2) Forum Konusu

Kısa Açıklama

Brütten Nete 2025 başlıklı bu içerikte, ilgili işlemlere yönelik olarak hazırlanan öğretici bir dosya yer almaktadır.
brutten-nete-2025.webp


Brütten Nete 2025, Excel formülleri ile 2025 yılına ait brüt ücretin netinin nasıl bulunacağını öğreten bir dosya yer almaktadır.

Excel ile Brütten Nete 2025​

ABCDEFGHIJKLMNOPQRSTUVWXY
1Aylar Brüt Ücret SGK Matrahı SGK Primi İŞSİZLİK Primi Gelir Vergisi Matrahı Kümülatif Gelir Vergisi Matrahı Gelir Vergisi 1 Gelir Vergisi 2 Gelir Vergisi 3 Gelir Vergisi 4 Gelir Vergisi 5 Toplam Gelir Vergisi AÜ Gelir Vergisi Matrahı Asgari Ücret Kümülatif Matrahı AÜGV1 AÜGV2 AÜGV3 AÜGV14 AÜGV5 Toplam Asgari Ücret Gelir Vergisi Kesilecek Gelir Vergisi Damga Vergisi Matrahı Damga Vergisi Net Hakediş
2Ocak 26.005,50 26.005,50 3.640,77 260,06 22.104,67 22.104,67 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 22.104,67 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
3Şubat 26.005,50 26.005,50 3.640,77 260,06 22.104,67 44.209,34 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 44.209,34 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
4Mart 26.005,50 26.005,50 3.640,77 260,06 22.104,67 66.314,01 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 66.314,01 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
5Nisan 26.005,50 26.005,50 3.640,77 260,06 22.104,67 88.418,68 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 88.418,68 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
6Mayıs 26.005,50 26.005,50 3.640,77 260,06 22.104,67 110.523,35 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 110.523,35 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
7Haziran 26.005,50 26.005,50 3.640,77 260,06 22.104,67 132.628,02 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 132.628,02 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
8Temmuz 26.005,50 26.005,50 3.640,77 260,06 22.104,67 154.732,69 3.315,70 0,00 0,00 0,00 0,00 3.315,70 22.104,67 154.732,69 3.315,70 0,00 0,00 0,00 0,00 3.315,70 0,00 0,00 0,00 22.104,67
9Ağustos 26.005,50 26.005,50 3.640,77 260,06 22.104,67 176.837,36 490,10 3.767,47 0,00 0,00 0,00 4.257,57 22.104,67 176.837,36 490,10 3.767,47 0,00 0,00 0,00 4.257,57 0,00 0,00 0,00 22.104,67
10Eylül 26.005,50 26.005,50 3.640,77 260,06 22.104,67 198.942,03 0,00 4.420,93 0,00 0,00 0,00 4.420,93 22.104,67 198.942,03 0,00 4.420,93 0,00 0,00 0,00 4.420,93 0,00 0,00 0,00 22.104,67
11Ekim 26.005,50 26.005,50 3.640,77 260,06 22.104,67 221.046,70 0,00 4.420,93 0,00 0,00 0,00 4.420,93 22.104,67 221.046,70 0,00 4.420,93 0,00 0,00 0,00 4.420,93 0,00 0,00 0,00 22.104,67
12Kasım 26.005,50 26.005,50 3.640,77 260,06 22.104,67 243.151,37 0,00 4.420,93 0,00 0,00 0,00 4.420,93 22.104,67 243.151,37 0,00 4.420,93 0,00 0,00 0,00 4.420,93 0,00 0,00 0,00 22.104,67
13Aralık 26.005,50 26.005,50 3.640,77 260,06 22.104,67 265.256,04 0,00 4.420,93 0,00 0,00 0,00 4.420,93 22.104,67 265.256,04 0,00 4.420,93 0,00 0,00 0,00 4.420,93 0,00 0,00 0,00 22.104,67

Adımlarımız:​

  • Kolay anlaşılması açısından Asgari Ücret değerleri ile yapılacaktır.
  • Normal SGK statüsünde çalışan kişileri kapsayan hesaplama yöntemine göre yapılacaktır.
  • Sadece Brütten Nete giden temel hesaplama kriterleri değerlerini baz alınacaktır.
İlk olarak hesaplamamızın başlıklarını tanımlayalım:

Brütten Nete Maaş Hesaplama Başlıkları​

  1. A1 hücresine Aylar yazın,
  2. B1 hücresine Brüt Ücret yazın,
  3. C1 hücresine SGK Matrahı yazın,
  4. D1 hücresine SGK Primi yazın,
  5. E1 hücresine İŞSİZLİK Primi yazın,
  6. F1 hücresine Gelir Vergisi Matrahı yazın,
  7. G1 hücresine Kümülatif Gelir Vergisi Matrahı yazın,
  8. H1 hücresine Gelir Vergisi 1 yazın,
  9. I1 hücresine Gelir Vergisi 2 yazın,
  10. J1 hücresine Gelir Vergisi 3 yazın,
  11. K1 hücresine Gelir Vergisi 4 yazın,
  12. L1 hücresine Gelir Vergisi 5 yazın,
  13. M1 hücresine Toplam Gelir Vergisi yazın,
  14. N1 hücresine AÜ Gelir Vergisi Matrahı yazın,
  15. O1 hücresine Asgari Ücret Kümülatif Matrahı yazın,
  16. P1 hücresine AÜGV1 yazın,
  17. Q1 hücresine AÜGV2 yazın,
  18. R1 hücresine AÜGV3 yazın,
  19. S1 hücresine AÜGV4 yazın,
  20. T1 hücresine AÜGV5 yazın,
  21. U1 hücresine Toplam Asgari Ücret Gelir Vergisi yazın,
  22. V1 hücresine Kesilecek Gelir Vergisi yazın,
  23. W1 hücresine Damga Vergisi Matrahı yazın,
  24. X1 hücresine Damga Vergisi yazın,
  25. Y1 hücresine Net Hakediş yazın,
Böylece Brütten Nete Maaş Hesaplaması için bize gerekli olan başlıkları oluşturmuş olduk.

Şimdi başlıklarımızın altına yazmamız gereken formüllere geçelim.

Kullanılacak Formüller​

Ay Bilgisi​

A2 hücresine Ocak, A3 hücresine Şubat yazın ve ikisini seçerek, sağ alt köşeden tutup 12 satır aşağıya çekin. Excel size 12 Ay'ın isimlerini yazacaktır. Dilerseniz Ayların numaralarını da yazabilrisiniz.

Brüt Ücret Bilgisi​

1. B2:B7 hücre aralığına 26.005,50 rakamını yazıyoruz. Bu rakam 2025 yılının ilk 6 aylık dilimine ait Brüt Asgari Ücrettir.
2. B8:B13 hücre aralığına 26.005,50 rakamını yazıyoruz. Bu rakam 2025 yılının ikinci 6 aylık dilimine ait Brüt Asgari Ücrettir.

SGK Matrahı​

İlk iki bilgi tamamen kullanıcılara dayalı ve istenilen şekilde girilen bilgi alanlarımızdı. Şimdi ise artık Excel Formüllerini konuşturma işlemine başlıyoruz.

1. C2 hücresine aşağıdaki formülü yazıyoruz ve C7 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.
Kod: 
=EĞER(B2>195041,40;195041,40;B2)
2. C8 hücresine aşağıdaki formülü yazıyoruz ve C13 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.
Kod: 
=EĞER(B8>195041,40;195041,40;B8)
Böylece formüllerimiz ile yazdığımız brüt ücretin SGK Tavanından büyük olması kontrolünü sağlamış olduk.

SGK Primi​

SGK Primi hesaplaması için D2 hücresine aşağıdaki formülü yazıyoruz ve D13 hücresine kadar kopyalıyoruz.
Kod: 
=YUVARLA(C2*14%;2)
Bu formül bize çalışanın maaşından kesilecek olan SGK Priminin rakamını verecektir.

İŞSİZLİK Primi​

İŞSİZLİK Primi hesaplaması için E2 hücresine aşağıdaki formülü yazıyoruz ve E13 hücresine kadar kopyalıyoruz.
Kod: 
=YUVARLA(C2*1%;2)
Bu formül bize çalışanın maaşından kesilecek olan İŞSİZLİK Priminin rakamını verecektir.

Gelir Vergisi Matrahı​

Bir çalışanın Gelir Vergisi hesaplamasını yapabilmek için referans alınan Gelir Vergisi Matrahı hesabı için formülümüz aşağıdaki gibi olacaktır.
Kod: 
=B2-TOPLA(D2:E2)
Üstteki formülü, F2 hücresine yapıştırıp; F13 hücresine kadar kopyalamanız gerekmektedir.

Kümülatif Gelir Vergisi Matrahı​

Bir çalışanın Gelir Vergisi hesaplamasını yapabilmek için referans alınan Kümülatif Gelir Vergisi Matrahı hesabı için formülümüz aşağıdaki gibi olacaktır.
Kod: 
=F2+EĞER(ESAYIYSA(G1);G1;0)
Üstteki formülü, G2 hücresine yapıştırıp; G13 hücresine kadar kopyalamanız gerekmektedir.

Gelir Vergisi 1​

Çalışanın maaşından kesilecek olan %15'lik vergi dilimini hesaplamak için H2 hücresine aşağıdaki formülü yapıştırıp, H13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((G2-F2)>=0;(G2-F2)<=158000);EĞER(G2<=158000;F2;110.000-(G2-F2))*0,15;EĞER((G2-F2)<0;EĞER(VE(G2>0;G2<=158000);(G2-0)*0,15;EĞER(G2>158000;(158000-0)*0,15;0));0))

Gelir Vergisi 2​

Çalışanın maaşından kesilecek olan %20'lik vergi dilimini hesaplamak için I2 hücresine aşağıdaki formülü yapıştırıp, I13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((G2-F2)>=158000;(G2-F2)<=330000);EĞER(G2<=330000;F2;330000-(G2-F2))*0,2;EĞER((G2-F2)<158000;EĞER(VE(G2>158000;G2<=330000);(G2-158000)*0,2;EĞER(G2>330000;(230.000-158000)*0,2;0));0))

Gelir Vergisi 3​

Çalışanın maaşından kesilecek olan %27'lik vergi dilimini hesaplamak için J2 hücresine aşağıdaki formülü yapıştırıp, J13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((G2-F2)>=330000;(G2-F2)<=1200000);EĞER(G2<=1200000;F2;1200000-(G2-F2))*0,27;EĞER((G2-F2)<330000;EĞER(VE(G2>330000;G2<=1200000);(G2-330000)*0,27;EĞER(G2>1200000;(1200000-330000)*0,27;0));0))

Gelir Vergisi 4​

Çalışanın maaşından kesilecek olan %35'lik vergi dilimini hesaplamak için K2 hücresine aşağıdaki formülü yapıştırıp, K13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((G2-F2)>=1200000;(G2-F2)<=4300000);EĞER(G2<=4300000;F2;4300000-(G2-F2))*0,35;EĞER((G2-F2)<1200000;EĞER(VE(G2>1200000;G2<=4300000);(G2-1200000)*0,35;EĞER(G2>4300000;(4300000-1200000)*0,35;0));0))

Gelir Vergisi 5​

Çalışanın maaşından kesilecek olan %40'lik vergi dilimini hesaplamak için L2 hücresine aşağıdaki formülü yapıştırıp, L13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER((G2-F2)>=4300000;F2*0,4;EĞER(G2>4300000;(G2-4300000)*0,4;0))

Toplam Gelir Vergisi​

Üstte 5 ayrı dilimde çalışanların Gelir Vergisi hesaplamasını yaptık. Toplam Gelir Vergisi alanını ise, aynı anda birden fazla vergi dilimine giren çalışanların ilgili ay'a ait gelir vergisi toplamının ne olduğunu görmek amacıyla oluşturduk. Bunun için M2 hücresine aşağıdaki formülü yazıp, M13 hücresine kadar kopyalamanız yeterli olacaktır.
Kod: 
=TOPLA(H2:L2)

Asgari Ücret Parametreleri​

2022 yılında değişen Maaş Hesaplama algoritması ile hayatımıza Asgari Ücret ... parametreleri de girmiş oldu. Şimdi bu parametreleri küçük açıklamalar ve hesaplama formülleri ile öğretelim.

AÜ Gelir Vergisi Matrahı​

Asgari Ücret Gelir Vergisi Matrahı, çalışanın SGK Matrahının Asgari Ücreti geçip geçmemesine bağlı olarak hesaplanan ve Asgari Ücret Gelir Vergisinin hesaplanması için gerekli olan alanımızdır. Bu hesaplamayı yapmak için:

1. N2:N7 hücre aralığına aşağıdaki formülü kopyalıyoruz.
Kod: 
=EĞER(B2<22104,67;B2;22104,67)
2. N8:N13 hücre aralığına ise formülünüzü küçük bir değişim ile aşağıdaki gibi kopyalıyoruz.
Kod: 
=EĞER(B8<22104,67;B8;22104,67)
Böylece yılın iki ayrı dilimindeki net asgari ücret rakamlarını kontrol ettirerek, Asgari Ücret Gelir Vergisi Matrahı rakamını bulmuş oluyoruz.

Asgari Ücret Kümülatif Matrahı​

Bu matrahımız, çalışanın maaşının asgari ücretin neti kadarına uygulanacak olan Gelir Vergisi Oranını tespit etmek içindir. Rakamı bulmak için O2 hücresine aşağıdaki formülü yazıp, O13 hücresine kadar kopyalıyoruz.
Kod: 
=N2+EĞER(ESAYIYSA(O1);O1;0)

AÜGV1​

Çalışanın maaşından kesilecek olan %15'lik asgari ücret vergi dilimini hesaplamak için P2 hücresine aşağıdaki formülü yapıştırıp, P13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((O2-N2)>=0;(O2-N2)<=158000);EĞER(O2<=158000;N2;158000-(O2-N2))*0,15;EĞER((O2-N2)<0;EĞER(VE(O2>0;O2<=158000);(O2-0)*0,15;EĞER(O2>158000;(158000-0)*0,15;0));0))

AÜGV2​

Çalışanın maaşından kesilecek olan %20'lik asgari ücret vergi dilimini hesaplamak için Q2 hücresine aşağıdaki formülü yapıştırıp, Q13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((O2-N2)>=158000;(O2-N2)<=330000);EĞER(O2<=330000;N2;330000-(O2-N2))*0,2;EĞER((O2-N2)<158000;EĞER(VE(O2>158000;O2<=330000);(O2-158000)*0,2;EĞER(O2>330000;(330000-158000)*0,2;0));0))

AÜGV3​

Çalışanın maaşından kesilecek olan %27'lik asgari ücret vergi dilimini hesaplamak için R2 hücresine aşağıdaki formülü yapıştırıp, R13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((O2-N2)>=330000;(O2-N2)<=1200000);EĞER(O2<=1200000;N2;1200000-(O2-N2))*0,27;EĞER((O2-N2)<330000;EĞER(VE(O2>330000;O2<=1200000);(O2-330000)*0,27;EĞER(O2>1200000;(1200000-330000)*0,27;0));0))

AÜGV4​

Çalışanın maaşından kesilecek olan %35'lik asgari ücret vergi dilimini hesaplamak için S2 hücresine aşağıdaki formülü yapıştırıp, S13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER(VE((O2-N2)>=1200000;(O2-N2)<=4300000);EĞER(O2<=4300000;N2;4300000-(O2-N2))*0,35;EĞER((O2-N2)<1200000;EĞER(VE(O2>1200000;O2<=4300000);(O2-1200000)*0,35;EĞER(O2>4300000;(4300000-1200000)*0,35;0));0))

AÜGV5​

Çalışanın maaşından kesilecek olan %40'lik asgari ücret vergi dilimini hesaplamak için T2 hücresine aşağıdaki formülü yapıştırıp, T13 hücresine kadar çoğaltmamız gerekmektetir.
Kod: 
=EĞER((O2-N2)>=4300000;N2*0,4;EĞER(O2>4300000;(O2-4300000)*0,4;0))

Toplam Asgari Ücret Gelir Vergisi​

Üstte 5 ayrı dilimde çalışanların Asgari Ücret Gelir Vergisi hesaplamasını yaptık. Toplam Asgari Ücret Gelir Vergisi alanını ise, aynı anda birden fazla vergi dilimine giren çalışanların ilgili ay'a ait gelir vergisi toplamının ne olduğunu görmek amacıyla oluşturduk. Bunun için U2 hücresine aşağıdaki formülü yazıp, U13 hücresine kadar kopyalamanız yeterli olacaktır.
Kod: 
=TOPLA(P2:T2)

Kesilecek Gelir Vergisi​

Artık bu aşamada çalışanın maaşından kesilecek olan işleme konu Gelir Vergisinin hesaplanması kaldı. Bunun için V2 hücresine aşağıdaki formülü yazıp, V13 hücresine kadar çoğaltıyoruz.
Kod: 
=YUVARLA(EĞER(M2-U2<=0;0;M2-U2);2)

Damga Vergisi Matrahı​

2022 yılının değişen maaş algoritmalarının etkilediği bir diğer husus ise Damga Vergisi oldu. Çalışanların maaşlarından Brüt Asgari Ücret kadar rakam damga vergisi hesaplamasından muaf edildi. Bu duruma bağlı olarak Damga Vergisi hesaplamasını yapabilmemiz için gerekli olan Damga Vergisi Matrahı hesabını şu şekilde yapıyoruz.
1. W2 hücresine aşağıdaki formülü yazıyoruz ve W7 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.
Kod: 
=EĞER(B2<=0;26005,50;B2-26005,50)
2. W8 hücresine aşağıdaki formülü yazıyoruz ve W13 hücresi de dahil olmak üzere aşağı doğru kopyalıyoruz.
Kod: 
=EĞER(B8<=0;26005,50;B8-26005,50)

Damga Vergisi​

Çalışanın maaşından kesmemiz gereken Damga Vergisini hesaplamak için X2 hücresine aşağıdaki formülü yazıyoruz ve X18 hücresine kadar yapıştırıyoruz.
Kod: 
=YUVARLA(W2*0,759%;2)

Net Hakediş​

Ve artık noktayı koyma zamanı...
Üstteki adım adım hesaplamalarımız neticesinde, Brüt Ücretimizden kesilen toplam 4 ana kalem vergisini düşerek çalışanın eline geçecek olan Net Hakediş rakamını bulalım. Bunun için Y2 hücresine aşağıdaki formülü yazıyoruz ve Y13 hücresine kadar kopyalıyoruz.
Kod: 
=B2-D2-E2-V2-X2

Sonuç​

Artık siz de kolayca bu formülleri kullanarak temel düzeyde bir maaş hesaplamasının nasıl yapıldığını öğrenebilirsiniz. Bu hesaplamadaki formüller, maaş hesabının en zor aşamalarından biri olan Gelir Vergisi hesaplamalarını da sorunsuzca yapmanızı sağlayacaktır.

Eğer Excel formüllerine biraz aşinaysanız; Gelir Vergisi hesabının nasıl yapıldığının mantığını da rahatça anlayabilirsiniz.

Netten Brüte hesaplama işlemlerini okumak için aşağıdaki linke tıklayabilirsiniz.
ExcelDepo

Netten Brüte Hesaplama 2025

Netten Brüte 2025 isimli içerikte, Excel formülleri ile 2025 yılına ait net ücretin brütünün nasıl bulunacağını öğreten bir yazı yer almaktadır.
Sorularınız için cevap kısmını kullanabilirsiniz.
  • Beğen

Toplu maaş hesaplaması için aşağıdaki ürünümüzü inceleyebilirsiniz.
www.exceldepo.com

Yıllık Maaş Bordrosu Hesaplama

En hızlı ve sınırsız çalışana ait Yıllık Maaş Bordrosu Hesaplama dosyası
www.exceldepo.com www.exceldepo.com
Umarım -biraz uzun olsa da- bu ipucu niteliğindeki yazımdan faydalananlar olur.
Boş Aidat Çizelgesi
Boş Aidat Çizelgesi  V1
Netten Brüte 2025
Netten Brüte 2025  2025-02-08
Yazar
ExcelDepo
İndirilme
1
Görüntüleme
77
İlk Yayınlama
Son Güncelleme

Derecelendirmeler

5.00 Oylama 2 İnceleme
Konuya Katıl

Sosyal Ağlarla Paylaş

Benzer Dosyalar Popüler İçerikler Daha Fazlası
Geri
Üst